Handout for the Actor-Partner Interdependence Model
M. Joy McClure, Adelphi University
Handout prepared as a supplement to:
McClure, M. J., Shrout, P. E. & Burke, C. T. (2017, June 23) Methods of Modeling Interdependence. Invited
session presented at the IARR Miniconference, Syracuse, NY.
SPSS Syntax for “The easy way”
Variables:
iosex = Examinee IOS
iospa = Partner IOS
cperptsupex = Examinee perceived support (mean centered)
cperptsuppa = Partner perceived support (mean centered)
*** Find the correlation between examinee and partner perceived support.
CORRELATIONS
/VARIABLES=cperptsupex cperptsuppa
/PRINT=TWOTAIL NOSIG0 /STATISTICS DESCRIPTIVES
/MISSING=PAIRWISE.
*** Regress examinee IOS onto actor and partner perceived support.
*** Then regress partner IOS onto actor and partner perceived support.
*** Save unstandardized residuals for later.
REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF OUTS R ANOVA
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT iosex
/METHOD=ENTER cperptsupex cperptsuppa
/SAVE RESID.
REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF OUTS R ANOVA
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT iospa
/METHOD=ENTER cperptsupex cperptsuppa
/SAVE RESID.
*** Now look at the correlation between the residuals.
CORRELATIONS
/VARIABLES=RES_1 RES_2
/PRINT=TWOTAIL NOSIG0 /STATISTICS DESCRIPTIVES
/MISSING=PAIRWISE.
SPSS Syntax for restructuring dyad dataset to stack dyad members and create dummy codes for TwoIntercept Model and effect code for Contrast Model
*** Making stacked file from the couples datafile.
*** First, you need a duplicate copy of your predictor variable, in our example perceived support.
COMPUTE cperptsupexcopy = cperptsupex.
COMPUTE cperptsuppacopy = cperptsuppa.
EXECUTE.
*** Then, the datafile can be restructured, changing some variables to cases and creating an index variable,
“evp”, which is equal to 1 for examinees and 2 for partners.
VARSTOCASES
/MAKE csupown FROM cperptsupex cperptsuppa
/MAKE csupoth FROM cperptsuppacopy cperptsupexcopy
/MAKE ios FROM iosex iospa
/INDEX=evp "EXAM = 1, PART = 2"(2)
/KEEP=couple
/NULL=KEEP.
*** Save this file.
SAVE OUTFILE='/Users/mjmcclure/MiniIARR2017/MethodsTalk/ IARR2017stackedmjm.sav'
/COMPRESSED.
*** Make examinee versus partner dummies and effect code.
COMPUTE examinee = 0.
COMPUTE partner = 0.
EXECUTE.
IF evp = 1 examinee = 1.
IF evp = 2 partner = 1.
EXECUTE.
COMPUTE exorpa = 0.
EXECUTE.
IF evp = 1 exorpa = 0.5.
IF evp = 2 exorpa = -0.5.
EXECUTE.
*** Save the file again.
SAVE OUTFILE='/Users/mjmcclure/MiniIARR2017/MethodsTalk/ IARR2017stackedmjm.sav'
/COMPRESSED.
SPSS Syntax for the Two-Intercept Model
*** Two-Intercept Model: Examinee versus Partner.
MIXED ios WITH examinee partner csupown csupoth
/FIXED = examinee partner csupown*examinee csupown*partner csupoth*examinee csupoth*partner |
NOINT
/PRINT = SOLUTION TESTCOV
/REPEATED = exorpa | subject(couple) COVTYPE(CSH).
Excerpt of SPSS Output for the Two-Intercept Model
Syntax for the Contrast (aka Interaction) Model
*** Contrast aka Interaction Model: Examinee vs Partner.
*** Using the partner dummy, making the examinee the baseline.
MIXED ios WITH csupown csupoth partner
/FIXED = csupown csupoth partner csupown*partner csupoth*partner
/PRINT = SOLUTION TESTCOV
/REPEATED = exorpa | SUBJECT(couple) COVTYPE(CSH).
Excerpt of SPSS Output for the Two-Intercept Model