4
The static general equilibrium model
This chapter develops a static general equilibrium model without and with governmental
activity. The model is called static since dynamic (i.e. intertemporal) aspects, such as
savings and investments, are excluded by assumption. Consequently, the capital stock
of the economy is constant and we concentrate on intersectoral allocation of resources
and labor-leisure choice. The discussion starts with the most simple model structure and
then successively introduces more complexities. The initial economy is closed, so that
international trade is excluded. In addition, we consider only a representative consumer
so that distributional effects of economic policy are disregarded. Then we successively
relax the assumptions of no international trade and perfect competition on all markets.
The representative household supplies his endowment of capital K̄ and labor L̄ to the
firms which use these inputs to produce output Y1 and Y2 of goods 1 and 2. Household
consumption is denoted by X1 and X2 respectively. The economic problem is to allocate
the scarce factor resources K and L to the two different types of firms in order to produce
an output combination which maximizes the utility of the representative household. The
latter is called an efficient allocation. In order to find the efficient allocation we first have to
specify preferences and technologies. In order to simplify the analysis we assume CobbDouglas preferences and technologies, i.e.
U (X1 , X2 ) = X1α X21−α
β
1− β i
Yi = Li i Ki
i = 1, 2.
In the next section, we develop the so-called "command optimum". This is the allocation
that would be chosen by a social planner who knows endowments, technologies and
preferences. After that we compare the command optimum to the allocation in a market
economy. Then we successively introduce various extension of the basic model.
4.1 The command optimum
In order to derive the command optimum, we formulate the allocation problem as a constrained maximization problem. As the representative household’s utility is to be maximized, the objective function is the utility function and the constraints are technologies
86
Chapter 4 –
The static general equilibrium model
and resource endowments, i.e.
max X1α X21−α
s.t.
X1 ,X2
β
1− β 1
X1 = L 1 1 K 1
L̄ = L1 + L2
,
and
β
1− β 2
X2 = L 2 2 K 2
K̄ = K1 + K2 .
The above formulation already assumes that all produced quantities are consumed, i.e.
Xi = Yi , i = 1, 2. The last assumption makes sense economically, since otherwise some
quantities would be wasted. For the formal derivation of the command optimum the
constraints are substituted into the objective function, so that the optimization problem
becomes
1− α
β 1− β α
max U ( L1 , K1 ) = L1 1 K1 1
( L̄ − L1 ) β2 (K̄ − K1 )1− β2
.
L1 ,K1
Figure 4.1 shows the graphical solution to the command optimum. Given factor endowments and technologies, it is possible to derive an efficiency locus in the factor space box
on the left side, where two production isoquants have the same slope. Since each point
on the efficiency locus defines a specific output combination, it can be transferred to the
transformation curve in the product space on the right hand side. The command optimum then is the point on the transformation curve, where the utility of the representative
consumer is maximized.
x2
x2
L1
efficiency
locus
x 2*
L
U(x1,x2)
Y1*
L2
Y2*
transformation
curve
K1
K2
x 1*
x1
K
Factor space box
Product space
Figure 4.1: The command optimum
For the numerical solution we specify endowments K̄ = 10 and L̄ = 20 as well as preference and technology parameters α = 0.3, β 1 = 0.3, β 2 = 0.6. Program 4.1 then computes
the solution to the problem using the minimization routine fminsearch. We thereby use
a module globals that stores our model parameters. The real*8 function utility, on the
other hand, returns the value of the utility function depending on L1 and K1 . Due to space
restrictions, however, we will show neither of them here.
4.1. The command optimum
87
Program 4.1: Planner solution to the static equilibrium model
program planner
! modules
use globals
use minimization
implicit none
! variable declaration and interface
real*8 :: x(2), L(2), K(2), Y(2), fret
interface
function utility(x)
real*8, intent(in) :: x(:)
real*8 :: utility
end function
end interface
! initial guess
x(:) = 5d0
! minimization routine
call fminsearch(x, fret, (/0d0, 0d0/), (/10d0, 20d0/), utility)
! solution
K(1) = x(1)
L(1) = x(2)
K(2) = Kbar - K(1)
L(2) = Lbar - L(1)
Y
= L**beta*K**(1d0-beta)
! Output
...
end program
The solution for the command optimum is
L1 = 3.53
K1 = 4.29
X1 = 4.04
L2 = 16.47
K2 = 5.71
X2 = 10.78.
The next step could be to change technology or preference parameters in order to check
how it affects the allocation. However, we proceed in a different direction and compute
the allocation of a market economy.
88
Chapter 4 –
The static general equilibrium model
4.2 The market solution
In order to derive the command optimum it was assumed that some central planner
knows the technologies, preferences and resource endowments. Of course, in reality there
is no such central planner. Usually households know their own endowments and preferences and firms know their own applied technologies, but all agents don’t know anything
about endowments, preferences and technologies of their respective competitors. On first
sight one could expect that the resource allocation in such a situation is quite random and
therefore very inefficient. However, as this section demonstrates, the interaction of supply and demand on goods and factor markets leads to an efficient allocation of resources
despite the fact that decisions of economic agents are decentralized. The driving force behind this surprising result is the price system, which guarantees an efficient information
exchange.
In the present model, two goods and two production factors are exchanged between firms
and households. Therefore we need four markets. With respect to prices one has to
distinguish between consumer prices pi and producer prices qi for the two consumer
goods and wage w and interest rate r for labor and capital inputs, respectively. We assume
perfect competition, i.e. prices are the same for all consumers and firms in the model and
firms do not make profits. Figure 4.2 shows the market system of our economy.
Demand X2
Demand X1
Good Market 2
(Price p2)
Good Market 1
(Price p1)
Supply Y2
Supply Y1
Firms producing
Good 1
Households
Supply L
Supply K
Labor Market
(Wage w)
Capital Market
(Interest rate r)
Firms producing
Good 2
Demand L1
Demand L2
Demand K1
Demand K2
Figure 4.2: Market system in the static general equilibrium model
Given consumer and factor prices, the representative household maximizes utility by
choosing consumption demand Xi and keeping in mind the budget constraint
max X1α X21−α
X1 ,X2
s.t.
p1 X1 + p2 X2 = w L̄ + r K̄ := Ȳ.
Taking derivatives with respect to X1 and X2 , we can calculate demand functions as
X1 =
α
Ȳ
p1
and
X2 =
1−α
Ȳ.
p2
(4.1)
4.2. The market solution
89
In the production sector firms maximize their profits Πi given their technology constraint
as well as producer and factor prices
max Πi = qi Yi − wLi − rKi
L i ,Ki
β
1− β i
s.t. Yi = Li i Ki
.
Again taking derivatives yields the input demand functions for firms producing good i
Li =
βi
qY
w i i
and
Ki =
1 − βi
qi Yi .
r
(4.2)
Since the simple economy abstracts from government activities, producer prices and consumer prices are identical, i.e. qi = pi . In the market economy, goods and factor prices
adjust until supply equals demand in all markets, i.e.
Xi = Yi
,
i = 1, 2 ,
L1 + L2 = L̄
and
K1 + K2 = K̄.
(4.3)
Since demand functions are homogenous of degree zero, only relative prices matter for
the equilibrium. Without loss of generality, it is possible to normalize the price of the first
good (i.e. q1 = p1 = 1.0) and vary the remaining three prices p2 , w, r. Consequently, one
only needs to consider three markets. When choosing three markets out of four, one has
to make sure that all four prices are used in the equations. This requirement is satisfied
with two goods markets and the labor market. After substituting factor demand functions
(4.2) and consumer demand functions (4.1) and rearranging the goods and factor market
equilibrium conditions (4.3), we obtain
1
−
p1
β1
w
β1 1 − β1
r
1− β 1
=0
β2 β2
1 − β 2 1− β 2
1
−
=0
p2
w
r
β2
β1
αȲ + (1 − α)Ȳ − L̄ = 0
w
w
(4.4)
(4.5)
(4.6)
Note that despite the fact that all four prices p1 , p2 , w, r are considered, the capital market
seems to be neglected. However, implicitly, it is also in equilibrium, since combining the
budget constraint of the household p1 X1 + p2 X2 = w L̄ + r K̄ and the zero profit condition
of firms pi Yi = wLi + rKi yields
p1 (X1 − Y1 ) + p2 (X2 − Y2 ) = w( L̄ − L1 − L2 ) + r (K̄ − K1 − K2 ).
This specific feature of our system is called Walras’ law. It says that, if n − 1 markets out of
n markets are in equilibrium, then the last market is automatically balanced. It would be
no problem to substitute the capital market and get rid of the labor market equilibrium.
However, in this special case it is not possible to substitute one of the two goods markets,
since only there the goods prices are used. For the computation of equilibrium prices in
our market system (4.4) to (4.6), Program 4.2 uses the rootfinding algorithm fzero. This
routine calculates the root of the market equations using Broydn’s method. The market
90
Chapter 4 –
The static general equilibrium model
Program 4.2: Market solution to the static equilibrium model
program market1
...
! initial guess
x(:) = 0.5d0
! find market equilibrium
call fzero(x, markets, check)
! check whether fzero converged
if(check)then
write(*,’(a/)’)’Error in fzero !!!’
stop
endif
...
end program
function markets(x)
...
! copy
p(1) =
p(2) =
w
=
r
=
prices
1d0
x(1)
x(2)
x(3)
! calculate total income
Ybar = w*Lbar+r*Kbar
! get market equations
markets(1) = 1d0/p(1)-(beta(1)/w)**beta(1)* &
((1d0-beta(1))/r)**(1d0-beta(1))
markets(2) = 1d0/p(2)-(beta(2)/w)**beta(2)* &
((1d0-beta(2))/r)**(1d0-beta(2))
markets(3) = beta(1)*alpha*Ybar/w+beta(2)* &
(1-alpha)*Ybar/w-Lbar
end function markets
equations are provided in the function markets, which receives a three dimensional price
vector. The entries in the price vector x are price for good 2 p2 , wage w and interest rate r.
Having copied the values of the vector to the respective variables, the function calculates
(4.4) to (4.6) and returns the respective values. Having determined the market prices p2 ,
4.3. Variable labor supply
91
w and r, the program checks whether fzero has actually converged. If this is the case,
we can calculate all economic variables of our model via (4.1), (4.2) and the production
technology.
Comparing the results from market and planner solution, we find that they yield exactly
the same quantities. Given the normalization p1 = 1, the remaining prices are p2 = 0.87,
w = 0.34 and r = 0.66.
4.3 Variable labor supply
Up to now it was assumed that households supply a fixed quantity of labor L̄ on the
market. In reality, however, they have to decide when to enter and leave the labor market
(extensive labor supply) and how much they want to work during a specific time span
(intensive labor supply). Consequently, it is useful to introduce a labor supply decision
on the household side. In the most simple case, leisure consumption is introduced as
an additional consumption good. The household then maximizes utility by choosing
consumption demand Xi and leisure demand F, keeping in mind the budget and time
constraint
max X1α1 X2α2 F1−α1 −α2
X1 ,X2 ,F
s.t.
p1 X1 + p2 X2 + wF = w T̄ + r K̄ := Ȳ,
where T̄ denotes the time endowment of the household. As before we derive the demand
functions
X1 =
α1
Ȳ
p1
,
X2 =
α2
Ȳ
p2
and
F=
1 − α1 − α2
Ȳ.
w
The labor supply decision has only little impact on the market equilibrium conditions.
The two goods markets (4.4) and (4.5) remain unchanged. Only the new labor market
equilibrium condition L1 + L2 = T̄ − F changes into
β1
β2
1 − α1 − α2
Ȳ − T̄ = 0.
α1 Ȳ + α2Ȳ +
w
w
w
(4.7)
The function we want to set equal to zero therefore changes to the one shown in Program
4.3. We thereby set T̄ = 30 and the new preference parameters α1 = 0.3 and α2 = 0.4.
4.4 Public goods and the government sector
Now we would like to introduce government activity into our model. The government
provides an exogenous level of the public good G and levies consumption and income
taxes in order to finance it. For simplicity it is assumed that the public good is equivalent
with good 1, but it would be no problem to specify a separate production technology.
92
Chapter 4 –
The static general equilibrium model
Program 4.3: Model with variable labor supply
function markets(x)
! parameter module
use globals
implicit none
! variable declaration
real*8, intent(in) :: x(:)
real*8 :: markets(size(x, 1))
real*8 :: Ybar, p(2), w, r
! copy
p(1) =
p(2) =
w
=
r
=
prices
1d0
x(1)
x(2)
x(3)
! calculate total income and consumer prices
Ybar = w*Tbar+r*Kbar
! get market equations
markets(1) = 1d0/p(1)-(beta(1)/w)**beta(1) &
*((1d0-beta(1))/r)**(1d0-beta(1))
markets(2) = 1d0/p(2)-(beta(2)/w)**beta(2) &
*((1d0-beta(2))/r)**(1d0-beta(2))
markets(3) = beta(1)*alpha(1)*Ybar/w+beta(2)*alpha(2)*Ybar/w+ &
(1d0-alpha(1)-alpha(2))*Ybar/w-Tbar
end function markets
Consequently, one has to distinguish between consumer and producer prices as well as
between gross and net factor prices
pi = qi (1 + τi )
,
wn = w(1 − τw )
and r n = r (1 − τr ),
where τi denote consumption tax rates and τw , τr define wage and interest income tax
rates, respectively. Figure 4.3 shows the model with government activity.
The budget constraint of consumers is now defined by
p1 X1 + p2 X2 + wn F = wn T̄ + r n K̄ := Ȳ n
yielding the new consumption and leisure demand functions
X1 =
α1 n
Ȳ
p1
,
X2 =
α2 n
Ȳ
p2
and and
F=
1 − α1 − α2 n
Ȳ .
wn
(4.8)
On the producer side, factor demand functions (4.2) do not change. Since the government
demands a share of the first good, the market equilibrium condition in the market for consumption good 1 changes to X1 + G = Y1 . The equilibrium condition on the second goods
4.4. Public goods and the government sector
93
Consumption
taxes τ1, τ2
Demand X2
Good Market 2
(Price p2=q2(1+τ2))
Demand X1
Good Market 1
(Price p1=q1(1+τ1))
Supply Y2
Supply Y1
Demand G
Firms producing
Good 1
Government
Households
Supply T-F
Labor Market
n
(Wage w =w(1-τw))
Supply K
Capital Market
n
(Interest rate r =r(1-τr))
Firms producing
Good 2
Demand L1
Demand L2
Demand K1
Demand K2
Capital and Labor
taxes τr, τw
Figure 4.3: Static general equilibrium with government
market remains unchanged, but one has to keep in mind the difference between producer
and consumer prices. Consequently, the two goods market equilibrium conditions (4.4)
and (4.5) change to
α1 Ȳ n
+G−
p1
β1
w
1 − β 1 1− β 1
α1Ȳ n
q1
+G = 0
r
p1
β2 β2
1 − β 2 1− β 2 q 2
1
−
= 0.
p2
w
r
p2
β1 The labor market equilibrium condition (4.7) now changes to
α1 Ȳ n
β
α Ȳ n 1 − α1 − α2 n
β1
q1
+ G + 2 q2 2 +
Ȳ − T̄ = 0.
w
p1
w
p2
wn
Finally, in equilibrium, all government outlays have to be financed by taxes, i.e.
q1 G =
2
∑ τi qi Xi + τw w(T̄ − F) + τr rK̄,
i =1
which yields – after substitution – the government budget equilibrium condition
τi
1 − α1 − α2 n
n
α Ȳ − τw w T̄ −
Ȳ − τr r K̄ = 0,
q1 G − ∑
1 + τi i
wn
i =1
2
where always one tax rate is endogenous and the remaining three other tax rates are
exogenous. Given G and the pre-specified exogenous tax rates, it is possible to solve
94
Chapter 4 –
The static general equilibrium model
the system of four equations (three markets and the government constraint) and four
unknowns (p2 , w, r and the endogenous tax rate). The function we want to set to zero is
shown in Program 4.4.
Program 4.4: Model with government activity
function markets(x)
! parameter module
use globals
implicit none
! variable declaration
real*8, intent(in) :: x(:)
real*8 :: markets(size(x, 1))
real*8 :: Ybarn, q(2), p(2), w, wn, r, rn
! copy producer prices and taxes
q(1)
= 1d0
q(2)
= x(1)
w
= x(2)
r
= x(3)
tauc(1) = x(4)
tauc(2) = 0.5d0*tauc(1)
! calculate consumer prices and total income
p
= q*(1d0+tauc)
wn
= w*(1d0-tauw)
rn
= r*(1d0-taur)
Ybarn = wn*Tbar+rn*Kbar
! get market equations
markets(1) = alpha(1)*Ybarn/p(1)+G-(beta(1)/w)**beta(1)* &
((1d0-beta(1))/r)**(1d0-beta(1))*q(1)*(alpha(1)*Ybarn/p(1)+G)
markets(2) = 1d0/p(2)-(beta(2)/w)**beta(2)* &
((1d0-beta(2))/r)**(1d0-beta(2))*q(2)/p(2)
markets(3) = beta(1)/w*q(1)*(alpha(1)*Ybarn/p(1)+G)+ &
beta(2)/w*q(2)*alpha(2)*Ybarn/p(2)+ &
(1d0-alpha(1)-alpha(2))*Ybarn/wn-Tbar
markets(4) = q(1)*G-tauc(1)/(1d0+tauc(1))*alpha(1)*Ybarn- &
tauc(2)/(1d0+tauc(2))*alpha(2)*Ybarn-&
tauw*(Tbar-(1d0-alpha(1)-alpha(2))/wn*Ybarn)-taur*r*Kbar
end function markets
In order to get an intuition of welfare effects of different tax structures in the above model,
Table 4.1 reports the results of some simulations with alternative tax rates. In each simulation, some tax rates are fixed and at least one tax rate is endogenously adjusted in order
to raise the required tax revenue to finance the public good. The first line reports the first-
4.5. Intermediate goods in production
τ1
0.00
0.76
0.00
0.35
0.18
0.50
τ2
τw
τr
95
w
r
q2
0.00 0.00 0.43 0.31 0.69 0.83
0.76 -0.76 0.00 0.31 0.69 0.83
0.00 0.26 0.26 0.33 0.67 0.86
0.35 0.00 0.00 0.33 0.67 0.86
0.18 0.00 0.20 0.32 0.68 0.85
0.25 0.00 0.00 0.34 0.66 0.87
X1
X2
3.93
3.93
3.72
3.72
3.81
3.38
6.31
6.31
5.75
5.75
5.99
6.20
F
U
12.88 6.78
12.88 6.78
15.02 6.73
15.02 6.73
14.10 6.76
14.84 6.72
In all simulations we assume q1 G = 3.0.
Table 4.1: General equilibrium with different tax structures in the static model
best optimum where only lump-sum taxes are levied and the tax system does not distort
individual decisions. As one can see in the next line, the first-best solution can also be
achieved with very high consumption taxes to finance public goods and subsidize labor
supply. The next simulation considers a pure income tax system. Since taxes now distort labor supply, leisure consumption increases dramatically, which drives up wages, so
that the household substitutes towards the less labor intensive good 1. As a consequence,
welfare in the last column declines compared to the first-best allocation. The following
simulation demonstrates that a consumption tax system with a uniform tax rate could be
equivalent to an income tax. As shown in the following line, welfare increases, if the tax
burden is shifted towards the lump-sum tax base. Finally, the last simulation of Table 4.1
considers a differentiated consumption tax where welfare decreases the most, since the
tax system distorts the consumption-leisure choice and the optimal consumption structure.
This should suffice to get a first idea how this so-called differential tax incidence analysis
works in numerical general equilibrium models. Of course, one could also vary the level
of public good consumption G and compute the resulting welfare effects for different
tax structures with a budget incidence analysis. In this case, however, utility from public
consumption has to be explicitly specified.
4.5 Intermediate goods in production
Up to now it was assumed that firms production is only used for final consumption. In
reality, however, firms also produce intermediate inputs for other firms. Consequently,
output demand of a specific sector does not only depend on final consumption demands,
but also on the output of all other sectors. Final demand changes in one sector may trigger output effects in all other sectors due to the changes in the demand for intermediate
inputs. In order to account for this interdependence of production sectors, the production structure of an economy is modeled by an input-output table, where Xij define input
96
Chapter 4 –
The static general equilibrium model
supplies from sector i to sector j of the economy. Table 4.2 displays the structure of such
a stylized IO-Table for the two-sector economy.
q1 X11
q2 X21
q1 X12
q2 X22
wL1
rK1
wL2
rK2
q1 Y1
q2 Y2
q 1 X1
q 2 X2
q1 G
q1 Y1
q2 Y2
Table 4.2: General structure of an IO-Table in a closed economy
Any IO-Table consists of three parts, the intermediate input table in the center, the final
demand table on the right side and the primary factor input table on the bottom. The
lines of the intermediate input and the final demand tables define the goods market equilibrium conditions which now change to
Y1 = X11 + X12 + X1 + G
Y2 = X21 + X22 + X2 .
The columns of the intermediate and primary factor input tables define the zero profit
conditions of the firms, i.e. qi Yi = qi Xii + q j X ji + wLi + rKi . In our example we abstract
from production taxes so that intermediate input prices are producer prices.
For the production sector we assume that output is produced with the input of intermeβ 1− β
diate goods Xij and a technology Li i Ki i for primary inputs. For simplicity, we assume
a Leontief overall production function
Yi = min
β
1− β i
Li i Ki
a0i
X ji
X
, ii ,
aii a ji
.
The advantage of such a production technology is that the fraction of primary and intermediate good inputs in production does not depend on prices, hence, is always constant.
We therefore have
β
1− β i
Li i Ki
Yi
= a0i
,
Xii
= aii
Yi
X ji
= a ji .
Yi
and
Consequently, given gross factor prices w and r, firms only choose the optimal combination of primary input factors via minimizing costs, i.e. the firms problem is given by
β
min wLi + rKi
L i ,Ki
1− β i
L iK
s.t. Yi = i i
a0i
.
4.5. Intermediate goods in production
97
Taking first order conditions of the resulting Lagrangean, we obtain the optimal primary
factor input relation
Ki
1 − βi w
=
.
Li
βi r
Substituting this relation into the technology constraint Yi =
mal primary factor input shares in production
1 − βi w βi
Ki
= a0i
ki =
Yi
βi r
and
β
1− β i
Li i Ki
a0i
, we obtain the opti-
β i r 1− β i
Li
li =
= a0i
.
Yi
1 − βi w
(4.9)
Dividing the zero profit condition of the firms
qi Yi = qi Xii + q j X ji + wLi + rKi
by output Yi and rearranging it therefore yields
(1 − aii )qi − a ji q j = wli + rki
,
i = 1, 2.
This is a linear equation system which we can write in matrix notation as
1 − a11 − a21
q1
wl1 + rk1
=
− a12 1 − a22
q2
wl2 + rk2
(4.10)
Given producer prices and tax rates, one can compute consumer prices pi = qi (1 + τi ), net
factor prices wn = w(1 − τw ) and r n = r (1 − τr ), net income Ȳ n and consumer demands
Xi , F from equation (4.8). The goods market equilibrium conditions can also be written in
matrix notation as
Y1
X1 + G
1 − a11 − a12
=
.
(4.11)
− a21 1 − a22
Y2
X2
We use this equation system to derive output levels Y1 and Y2 . Note that the coefficient matrix on the left hand side now differs from the one in the zero profit condition
above. Given output quantities, factor demands are computed from (4.9). Finally, the factor market equilibrium conditions and the government budget constraint can be checked
for equality.
Summing up, the solution to the model with intermediate goods can be computed in the
following steps:
1. Given factor prices w, r as well as tax rates τ1 , τ2 , τw and τr , calculate ki and li from
(4.9).
2. Determine produces prices qi via (4.10).
98
Chapter 4 –
The static general equilibrium model
3. Calculate consumer prices pi and net factor prices wn and r n in order to derive demands X1 , X2 and F from (4.8).
4. Having calculated demands, determine output levels via (4.11).
5. Again use (4.9) to compute Ki and Li .
6. Check all remaining markets and the government budget for clearance, i.e.
L1 + L2 + F − T̄ = 0
K1 + K2 − K̄ = 0
τi
Xi − τw w( L1 + L2 ) − τr r K̄ = 0.
q
i
i =1
2
q1 G − ∑
If this is not the case, adjust w, r and the endogenous tax rate (e.g. via using fzero)
in order to find market clearing prices and the government budget clearing tax rate.
Program 4.5 shows the function needed for the computation of the intermediate input
model for the input coefficients: a11 = a22 = 0.0, a12 = 0.3 and a21 = 0.2. The first
major difference between this program and the ones before is that we now define all
economic variables in the module globals. The reason for this is that now, in opposite
to the previous versions, we already have to compute all those variables in the function
markets. We can therefore use the computations in the function and take the resulting
variables for producing the program’s output in order to avoid double computation. Note
that, beneath the module globals in which all our parameters and variables are stored,
we now also have to use the matrixtools module to compute prices qi and output levels
Yi from the linear equation system.
The function now takes only a two dimensional array as input. As we now determine
both producer prices q1 and q2 via a linear equation system, we can not normalize the
producer price of the first consumption good. Therefore, we chose to normalize the gross
wage w to 1.0.13 Then, only the interest rate and the government consumption tax rate
is endogenous. We thereby assume that the consumption tax is uniform across different
consumption goods and there is no income tax. We then follow the six steps described
above in order to calculate the capital market equilibrium condition and the government’s
budget constraint. Note that we use lu_solve for calculating both producer prices an
output levels. Recall that this routine gets two input arguments A and b which are the
matrix and the vector defining the linear equation system Ax = b. lu_solve then computes the solution x to the system and stores it in the vector b.
Rather than only normalizing wage, in practice, the prices of the initial equilibrium are
normalized to qi = w = r = 1.0, so that the observed nominal values in the IO-Table
reflect physical quantities from where one can compute the preference and technology
13
Without normalization any arbitrary starting point of prices and tax rates would yield the same quantities but arbitrary equilibrium prices.
4.5. Intermediate goods in production
99
Program 4.5: Model with intermediate goods
function markets(x)
! parameter module
use globals
use matrixtools
...
! copy producer prices and taxes
w
= 1d0
r
= x(1)
tauc(1) = x(2)
tauc(2) = tauc(1)
! 1. calkulate K/Y and L/Y
ky = a0*((1d0-beta)/beta*w/r)**beta
ly = a0*(beta/(1d0-beta)*r/w)**(1d0-beta)
! 2. determine producer prices
q = w*ly+r*ky
call lu_solve(ID-transpose(a), q)
! 3. consumer prices and demands
p = q*(1d0+tauc)
wn = w*(1d0-tauw)
rn = r*(1d0-taur)
Ybarn = wn*Tbar+rn*Kbar
XD = alpha/p*Ybarn
F = (1d0-alpha(1)-alpha(2))/wn*Ybarn
! 4.
Y(1)
Y(2)
call
determine output levels
= XD(1)+G
= XD(2)
lu_solve(ID-a, Y)
! 5. compute K and L
K = ky*Y
L = ly*Y
! 6. check markets and budget
markets(1) = K(1)+K(2)-Kbar
markets(2) = q(1)*G-sum(tauc*q*XD)-tauw*w*(Tbar-F)-taur*r*Kbar
end function markets
parameters. The latter procedure is called calibration of parameters. The numerical example we show here does not calibrate the preference and technology parameters from an
observed equilibrium allocation. Instead parameters are specified exogenously and the
100
Chapter 4 –
The static general equilibrium model
resulting equilibrium allocation is computed as described above. The left part of Table 4.3
reports the initial equilibrium for the parameter and endowment specification described
above. We chose G = 3.0 as in the simulation in the preceding section.
0.00
5.47
5.46 13.50 2.27 21.23
0.00 18.00
23.47
0.00
5.36
5.65 13.41 2.64 21.69
0.00 17.88
23.24
4.73 10.81
11.03 7.20
4.90 10.56
11.43 7.04
21.23 23.47
21.69 23.24
w = 1.00, r = 1.82, q1 = 0.76, q2 = 0.97
w = 1.00, r = 2.31, q1 = 0.88, q2 = 1.09
τ1 = τ2 = 0.07, p1 = 0.81, p2 = 1.04
τ1 = τ2 = 0.08, p1 = 0.95, p2 = 1.18
Table 4.3: Initial (with K̄ = 10) and final (with K̄ = 8) structure of the economy
It is no problem to derive leisure consumption, tax revenues and the welfare level. As
in the previous section one could now alter the tax structure and compute the resulting
new equilibrium structure of the economy. Alternatively one could also adjust factor endowments. Assume, for example, that capital inputs in production give rise to carbon
emissions E and that there is a linear relationship Ei = κKi for emissions in each production sector. Consequently, the government could introduce a trading scheme for carbon
emissions and reduce the quantity of emissions by 20 percent. In our model such a policy would simply reduce the endowment of capital from K̄ = 10 to K̄ = 8. The right
part of Table 4.3 shows how such a policy would change the structure of the economy.
Of course, due to the reduced endowment, the price of capital would increase, inducing
the intended reduction in demand. As a consequence, producer prices increase in both
sectors reducing the private demand for final goods. Due to higher producer prices, also
consumption tax rates have to increase from 7 to 8 percent.
4.6 Open economies and international trade
Up to now we have only considered a closed economy model. In order to analyze consequences of international trade in goods and production factors, we have to open the
economy for imports and exports. In principle there are two options to model that. If
the home country is small compared to other countries and therefore policies of the home
country do not influence international goods and factor prices, it is not necessary to consider the foreign country explicitly in the numerical model. For the small open economy
(SMOPEC), prices of the traded goods and factors are simply given by the international
market and the domestic production sector and privat demands adjust to these prices.
However, if the home economy is large compared to other countries, so that domestic
polices do affect international prices, one has to consider the foreign countries explicitly.
4.6. Open economies and international trade
101
In the following, we focus on the most simple case with two large countries, where home
country variables are denoted by the superscript A and the foreign variables are denoted
by the superscript B. For simplicity we assume that both countries have identical preferences and technologies. They only differ with respect to their endowments. Let’s assume
that the home country A (i.e. an industrialized country of the north) is endowed with
qualified labor, but is short with capital (or natural resources), while the foreign country
B (i.e. an oil exporting country of the south) is endowed with natural resources and short
with qualified labor. More specifically we assume
T̄ A = 30, K̄ A = 10 and
T̄ B = 10, K̄ B = 30.
As before, it is assumed that governments have to provide public goods G = 3.0 financed
by uniform consumption taxes. Table 4.4 then shows the autarky equilibrium for both
countries without any trade.
0.00
5.47
5.46 13.50 2.27 21.23
0.00 18.00
23.47
0.00
2.41
1.29 4.41 0.55
0.00 5.88
4.73 10.81
11.03 7.20
1.15
11.43
4.20
7.04
21.23 23.47
6.25
8.29
6.25
8.29
w = 1.00, r = 1.82, q1 = 0.76, q2 = 0.97
w = 1.00, r = 0.18, q1 = 0.18, q2 = 0.35
τ1 = τ2 = 0.07, p1 = 0.81, p2 = 1.04
τ1 = τ2 = 0.05, p1 = 0.19, p2 = 0.37
U = 16.99
U = 12.70
Table 4.4: Autarky equilibrium for two-country model
It should not be surprising that – given the specific normalization w = 1.0 – the equilibrium interest rate is much higher in the home country than in the foreign country.
Consequently, the producer price of the capital intensive good 1 is relatively high in the
home country, so that the demand structure is shifted towards the labor intensive good
2. Given our endowments, technologies and preferences, the autarky welfare level in the
home country is higher than in the foreign country.
Next, we assume that goods 2 and capital are traded internationally, while good 1 and
labor can not be traded. In equilibrium, on the one hand, there now are two domestic
goods markets for good 1 and two domestic labor markets in both countries. On the
other hand, there are two international markets for good 2 and capital
A
A
B
B
+ X22
+ X2A + X21
+ X22
+ X2B = Y2A + Y2B
X21
K1A + K2A + K1B + K2B = K̄ A + K̄ B
With respect to goods and factor prices we have to distinguish three factor prices w A , w B
and r which determine the producer prices q1A , q1B and q2 . We can solve for the producer
102
Chapter 4 –
The static general equilibrium model
prices q1A and q2 of the home country via solving (4.10). For the foreign country, we then
have
(1 − a11 )q1B − a21 q2 = wl1B + rk1B
from the zero profit condition. As q2 is the same for both countries it is easy to solve for q1B .
In in order to derive producer prices, consumer prices and final demands we follow the
approach of the closed economy. However, when it comes to computing output quantities
YiA , YiB one has to supplement the three goods markets by one factor market which is the
labor market of the home country in our example. Therefore, we have
⎤
⎤⎡ A ⎤ ⎡
⎡
0
0
X1A + G
Y1
1 − a11 − a12
⎥ ⎢
⎥
⎢
⎢ −a
1 − a22 − a21 1 − a22 ⎥
⎥ ⎢ Y2A ⎥ ⎢ X2A + X2B ⎥
⎢
21
⎥
⎥⎢ B ⎥ = ⎢
⎢
⎣
0
0
1 − a11 − a12 ⎦ ⎣ Y1 ⎦ ⎣ X1B + G ⎦
T̄ A − F A
l1A
l2A
0
0
Y2B
We then again proceed like in the closed economy case. Given output quantities we can
compute factor demands and check the equilibrium on factor markets and the two public
budgets. Program 4.6 shows parts of the function we use for computing the equilibrium
allocation. Table 4.5 shows the equilibrium for both countries when they are opened up
for trade.
0.00
5.54
0.00
2.80
0.00 7.71 1.10
0.00 8.82
0.00 10.28
-13.05 0.03
3.58 15.70
8.34 10.46
1.81
4.21
0.01
0.01
17.46 32.26
8.82
0.03
wA
6.10 10.26 1.10 0.00 17.46
0.00 13.67
13.05 32.26
= 1.00, r = 0.58, q1 = 0.37, q2 = 0.58
τ1A = τ2 = 0.05 A ,
U A = 19.58
p1A = 0.38, p2A = 0.61
τ1B = τ2B = 0.06, p1B = 0.39, p2B = 0.62
U B = 14.78
Table 4.5: Trade equilibrium for two-country model
As one would expect the home country A imports capital from the foreign country and
exports goods 2. In equilibrium the trade balance has to be in equilibrium for every
country which implies
h
h
− X22
− X2h = r K̄ h − K1h − K2h
(4.12)
q2 Y2h − X21
, h = A, B.
Note that compared to the autarky equilibrium both countries benefit from trade.
4.6. Open economies and international trade
Program 4.6: Model with international trade
function markets(x)
...
! 1. calkulate K/Y and L/Y
...
! 2. determine producer prices
q(:,1) = w(1)*ly(:,1)+r*ky(:,1)
call lu_solve(ID-transpose(a), q(:,1))
q(1,2) = (a(2,1)*q(2,1)+w(2)*ly(1,2)+r*ky(1,2))/(1d0-a(1,1))
q(2,2) = q(2,1)
! 3. consumer prices and demands
...
! 4. determine output levels
vec(1) = Xd(1,1)+G
vec(2) = Xd(2,1)+Xd(2,2)
vec(3) = Xd(1,2)+G
vec(4) = Tbar(1)-F(1)
mat(1,
mat(2,
mat(3,
mat(4,
:)
:)
:)
:)
=
=
=
=
(/1d0-a(1,1), -a(1,2), 0d0, 0d0/)
(/-a(2,1), 1d0-a(2,2), -a(2,1), 1d0-a(2,2)/)
(/0d0, 0d0, 1d0-a(1,1), -a(1,2)/)
(/ly(1,1), ly(2,1), 0d0, 0d0/)
call lu_solve(mat, vec)
Y(1,1) = vec(1)
Y(2,1) = vec(2)
Y(1,2) = vec(3)
Y(2,2) = vec(4)
! 5. compute K and L
...
! 6. check markets and budget
markets(1) = L(1,2)+L(2,2)-(Tbar(2)-F(2))
markets(2) = sum(K)-sum(Kbar)
markets(3) = q(1,1)*G-sum(tauc(:,1)*q(:,1)*Xd(:,1))-&
tauw(1)*w(1)*(Tbar(1)-F(1))-taur(1)*r*Kbar(1)
markets(4) = q(1,2)*G-sum(tauc(:,2)*q(:,2)*Xd(:,2))-&
tauw(2)*w(2)*(Tbar(2)-F(2))-taur(2)*r*Kbar(2)
end function markets
103